myx/MyxCMake/lib/DownloadContent.cmake

#[=======================================================================[.rst:
myx_download_content
-----------------------

Функция для загрузки дополнительных репозиториев::

  myx_download_content(NAME
    [ DOWNLOAD_DIR dir ] |
    [ GIT_REPOSITORY url ] |
    [ GIT_TAG tag ] |
    [ AUTOFETCH ] | [ AUTOPULL ] )

Обязательный параметр: `NAME` - имя целевого каталога.
Параметр `DOWNLOAD_DIR` содержит имя каталога, в который будет загружаться
содержимое (по умолчанию `_downloads`).
Параметр `GIT_REPOSITORY` содержит адрес внешнего проекта, который нужно
загрузить с помощью git.
Параметр `GIT_TAG` содержит используемые метку, идентификатор коммита или
ветку в загружаемом репозитории.
Если указана опция `AUTOFETCH`, то на этапе конфигурирования для загруженного
репозитория будут скачиваться изменения.
Если указана опция `AUTOPULL`, то на этапе конфигурирования из загруженного
репозитория будет изменяться рабочий каталог.

#]=======================================================================]

find_package(Git QUIET)

option(ENABLE_DOWNLOAD_CONTENT "Enable download content" ON)

if(CMAKE_SCRIPT_MODE_FILE)
  include(${CMAKE_CURRENT_LIST_DIR}/ProjectIsTopLevel.cmake)
endif()

function(myx_download_content NAME)
  set(options AUTOFETCH AUTOPULL)
  set(oneValueArgs)
  set(multiValueArgs DOWNLOAD_DIR GIT_REPOSITORY GIT_TAG)
  cmake_parse_arguments(ARG "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  if(NOT CMAKE_SCRIPT_MODE_FILE)
    if(TARGET myx-download-${NAME})
      return()
    else()
      add_custom_target(myx-download-${NAME})
    endif()
    if(NOT TARGET myx-download-content)
      add_custom_target(myx-download-content)
    endif()
  endif()

  if(NOT PROJECT_IS_TOP_LEVEL)
    return()
  endif()

  if(NOT ARG_DOWNLOAD_DIR)
    set(ARG_DOWNLOAD_DIR "_downloads")
  endif()

  if(CMAKE_SCRIPT_MODE_FILE)
    set(PROJECT_SOURCE_DIR ${CMAKE_CURRENT_LIST_DIR})
  endif()
  set(ARG_DOWNLOAD_DIR ${PROJECT_SOURCE_DIR}/${ARG_DOWNLOAD_DIR})

  if(NOT IS_DIRECTORY ${ARG_DOWNLOAD_DIR})
    execute_process(COMMAND ${CMAKE_COMMAND} -E make_directory ${ARG_DOWNLOAD_DIR})
  endif()

  set(WORK_DIR "${ARG_DOWNLOAD_DIR}/${NAME}")
  if(ENABLE_DOWNLOAD_CONTENT AND GIT_EXECUTABLE AND ARG_GIT_REPOSITORY)
    if(NOT IS_DIRECTORY ${WORK_DIR})
      execute_process(COMMAND ${GIT_EXECUTABLE} clone ${ARG_GIT_REPOSITORY} ${NAME}
                      WORKING_DIRECTORY ${ARG_DOWNLOAD_DIR})
    else()
      if(ARG_AUTOFETCH)
        execute_process(COMMAND ${GIT_EXECUTABLE} fetch
                        WORKING_DIRECTORY ${WORK_DIR})
      endif()
    endif()
    if(ARG_GIT_TAG)
      execute_process(COMMAND ${GIT_EXECUTABLE} checkout ${ARG_GIT_TAG}
                      WORKING_DIRECTORY ${WORK_DIR})
    else()
      if(ARG_AUTOPULL)
        execute_process(COMMAND ${GIT_EXECUTABLE} pull
                        WORKING_DIRECTORY ${WORK_DIR})
      endif()
    endif()
  endif()

  if(NOT CMAKE_SCRIPT_MODE_FILE AND EXISTS "${WORK_DIR}/CMakeLists.txt")
    add_subdirectory(${WORK_DIR} EXCLUDE_FROM_ALL)
  endif()
endfunction()