myx/lib/Qt5TargetSetup.cmake

include_guard(GLOBAL)

function(myx_qt5_target_setup NAME)
  set(options)
  set(oneValueArgs)
  set(multiValueArgs COMPONENTS PRIVATE PUBLIC_MOC PRIVATE_MOC UI QRC LANGS)

  cmake_parse_arguments(ARG "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  get_target_property(type ${NAME} TYPE)

  if(ARG_COMPONENTS)
    find_package(Qt5 COMPONENTS ${ARG_COMPONENTS} REQUIRED)
    foreach(iter ${ARG_COMPONENTS})
      target_include_directories(${NAME} PRIVATE ${Qt5${iter}_INCLUDE_DIRS})
      if(type STREQUAL "EXECUTABLE" AND NOT iter STREQUAL "LinguistTools")
        target_link_libraries(${NAME} PRIVATE "Qt5::${iter}")
      endif()
    endforeach()
  endif()

  if(ARG_PRIVATE)
    foreach(iter ${ARG_PRIVATE})
      find_package("Qt5${iter}" COMPONENTS Private REQUIRED)
      target_include_directories(${NAME} PRIVATE ${Qt5${iter}_PRIVATE_INCLUDE_DIRS})
    endforeach()
  endif()

  if(type STREQUAL "EXECUTABLE")
    target_compile_options(${NAME} PRIVATE ${Qt5Core_EXECUTABLE_COMPILE_FLAGS})
  endif()

  if(ARG_PUBLIC_MOC)
    set_property(TARGET ${NAME} APPEND PROPERTY PUBLIC_HEADER_FILES "${ARG_PUBLIC_MOC}")
    set_property(TARGET ${NAME} APPEND PROPERTY TR_FILES ${ARG_PUBLIC_MOC})
  endif()

  if(ARG_PRIVATE_MOC)
    set_property(TARGET ${NAME} APPEND PROPERTY PRIVATE_HEADER_FILES "${ARG_PRIVATE_MOC}")
    set_property(TARGET ${NAME} APPEND PROPERTY TR_FILES ${ARG_PRIVATE_MOC})
  endif()

  if(ARG_PUBLIC_MOC OR ARG_PRIVATE_MOC)
    qt5_wrap_cpp(moc_cpp ${ARG_PUBLIC_MOC} ${ARG_PRIVATE_MOC})
  endif()

  if(ARG_QRC)
    qt5_add_resources(qrc_cpp ${ARG_QRC})
  endif()

  if(ARG_UI AND "Widgets" IN_LIST ARG_COMPONENTS)
    qt5_wrap_ui(ui_h ${ARG_UI})
    set_property(TARGET ${NAME} APPEND PROPERTY TR_FILES ${ARG_UI})
    # TODO
    target_include_directories(${PROJECT_NAME} PRIVATE ${PROJECT_BINARY_DIR})
  endif()

  # Формирование файла ресурсов с переводами
  if("LinguistTools" IN_LIST ARG_COMPONENTS)
    # Заглавие файла ресурсов
    file(WRITE ${PROJECT_BINARY_DIR}/${NAME}_l10n.qrc "<RCC><qresource prefix=\"/qm\">\n")
    # Перечень файлов, подлежащих переводу
    get_target_property(tr ${NAME} TR_FILES)
    # Для каждого языка, указанное в параметре LANGS
    foreach(iter ${ARG_LANGS})
      # Создание или обновление файла переводов в каталоге ${PROJECT_SOURCE_DIR}/l10n
      # и его компиляция в каталог ${PROJECT_BINARY_DIR}
      qt5_create_translation(qm ${tr} "${PROJECT_SOURCE_DIR}/l10n/${NAME}_${iter}.ts")
      # Добавление записи для скомпилированного файла переводов в ресурсный файл
      file(APPEND ${PROJECT_BINARY_DIR}/${NAME}_l10n.qrc
        "<file alias=\"${NAME}_${iter}\">${NAME}_${iter}.qm</file>\n")
      # Добавление скомпилированного файла переводов к списку зависимостей для цели
      target_sources(${NAME} PRIVATE ${qm})
    endforeach()
    # Окончение файла ресурсов
    file(APPEND ${PROJECT_BINARY_DIR}/${NAME}_l10n.qrc "</qresource></RCC>\n")
    # Комплияция файла ресурсов с переводами
    qt5_add_resources(qrc_l10n ${CMAKE_BINARY_DIR}/${NAME}_l10n.qrc)
  endif()
  target_sources(${NAME} PRIVATE ${ARG_PUBLIC_MOC} ${ARG_PRIVATE_MOC} ${moc_cpp} ${ui_h} ${qrc_cpp} ${qrc_l10n})

  # Установка публичных заголовочных файлов
  if(PROJECT_IS_TOP_LEVEL)
    install_relative(${PROJECT_SOURCE_DIR}
      FILES ${ARG_PUBLIC_MOC}
      DESTINATION ${CMAKE_INSTALL_PREFIX}
      COMPONENT dev
     )
  endif()
endfunction()