1.99.90

2022-10-05 11:35:08 +03:00
parent 572b0be826
commit a061ebb7a9
36 changed files with 74 additions and 5 deletions
--- a/MyxCMake/lib/AddLibrary.cmake
+++ b/MyxCMake/lib/AddLibrary.cmake
@ -0,0 +1,220 @@
+#[=======================================================================[.rst:
+myx_add_library
+---------------
+
+Вспомогательная функция для создания библиотеки::
+
+    myx_add_library(NAME TYPE
+      [ OUTPUT_NAME output_name ] |
+      [ EXPORT_FILE_NAME file_name ] |
+      [ EXPORT_BASE_NAME base_name ])
+
+Обязательные параметры: `NAME` - имя библиотеки и `TYPE` - тип цели.
+Параметр `OUTPUT_NAME` определяет базовое имя выходных файлов.
+Параметр `EXPORT_FILE_NAME` задаёт имя заголовочного файла экспортируемых
+переменных, а `EXPORT_BASE_NAME` - базовый суффикс для формирования имён переменных.
+Все остальные параметры передаются в стандартную функцию `add_library()`
+
+#]=======================================================================]
+
+include_guard(GLOBAL)
+
+include(CMakePackageConfigHelpers)
+include(GenerateExportHeader)
+
+function(myx_add_library NAME TYPE)
+  set(options)
+  set(oneValueArgs OUTPUT_NAME EXPORT_FILE_NAME EXPORT_BASE_NAME)
+  set(multiValueArgs)
+
+  cmake_parse_arguments(ARG "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
+
+  if(NOT ARG_OUTPUT_NAME)
+    set(ARG_OUTPUT_NAME ${NAME})
+  endif()
+
+  # Вызов стандартной функции `add_library()`
+  add_library(${NAME} ${TYPE} ${ARG_UNPARSED_ARGUMENTS})
+
+  if(TYPE STREQUAL "INTERFACE")
+    # Библиотека, состоящая только из заголовочных файлов не требует сборки.
+    # Стандартные пути к заголовочным файлам
+    target_include_directories(${NAME}
+      INTERFACE
+        $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include>
+        $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
+    )
+  else()
+    string(TOUPPER ${NAME} PROJECT_NAME_UPPER)
+    # Опция для разрешения сборки динамической библиотеки
+    cmake_dependent_option(${PROJECT_NAME_UPPER}_BUILD_SHARED
+      "Build shared library for ${NAME}" ON "BUILD_SHARED_LIBS" OFF)
+    # Опция для разрешения сборки статической библиотеки
+    cmake_dependent_option(${PROJECT_NAME_UPPER}_BUILD_STATIC
+      "Build static library for ${NAME}" ON "NOT BUILD_SHARED_LIBS" OFF)
+
+    # Стандартные пути к заголовочным файлам
+    target_include_directories(${NAME}
+      PUBLIC
+        $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include>
+      PRIVATE
+        $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/src>
+        $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
+    )
+
+    # Сборка позиционно-независимых объектных файлов нужна
+    # для создания динамической библиотеки
+    set_target_properties(${NAME} PROPERTIES POSITION_INDEPENDENT_CODE ON)
+
+    if(NOT EXPORT_BASE_NAME)
+      string(TOUPPER ${NAME} ARG_EXPORT_BASE_NAME)
+    endif()
+
+    if(NOT ARG_EXPORT_FILE_NAME)
+      set(ARG_EXPORT_FILE_NAME "${PROJECT_SOURCE_DIR}/include/${NAME}/${NAME}_export.hpp")
+    endif()
+
+    generate_export_header(${NAME}
+      BASE_NAME ${ARG_EXPORT_BASE_NAME}
+      EXPORT_MACRO_NAME "EXPORT_${ARG_EXPORT_BASE_NAME}"
+      DEPRECATED_MACRO_NAME "DEPRECATED_${ARG_EXPORT_BASE_NAME}"
+      NO_DEPRECATED_MACRO_NAME "NO_DEPRECATED_${ARG_EXPORT_BASE_NAME}"
+      NO_EXPORT_MACRO_NAME "NO_EXPORT_${ARG_EXPORT_BASE_NAME}"
+      STATIC_DEFINE "STATIC_DEFINE_${ARG_EXPORT_BASE_NAME}"
+      EXPORT_FILE_NAME ${ARG_EXPORT_FILE_NAME}
+      DEFINE_NO_DEPRECATED
+    )
+    set_property(TARGET ${NAME} APPEND PROPERTY INTERFACE_HEADER_FILES "${ARG_EXPORT_FILE_NAME}")
+
+    # Цель для создания динамической библиотеки из объектных файлов
+    if(${PROJECT_NAME_UPPER}_BUILD_SHARED)
+      # Для создания динамической библиотеки используются объектные файлы цели ${NAME}
+      add_library(${NAME}_shared SHARED $<TARGET_OBJECTS:${NAME}>)
+      # Установка дополнительных свойств для цели ${NAME}_shared
+      # VERSION:     версия библиотеки
+      # SOVERSION:   мажорная версия библиотеки
+      # LIBRARY_OUTPUT_DIRECTORY: каталог для записи результатов сборки
+      # OUTPUT_NAME: базовое имя выходного файла (без учёта расширения)
+      set_target_properties(${NAME}_shared
+        PROPERTIES
+          VERSION ${PROJECT_VERSION}
+          SOVERSION ${PROJECT_VERSION_MAJOR}
+          LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_LIBDIR}
+          OUTPUT_NAME ${ARG_OUTPUT_NAME})
+    endif()
+
+    # Цель для создания статической библиотеки из объектных файлов
+    if(${PROJECT_NAME_UPPER}_BUILD_STATIC)
+      # Для создания статической библиотеки используются объектные файлы цели ${NAME}
+      add_library(${NAME}_static STATIC $<TARGET_OBJECTS:${NAME}>)
+      # Установка дополнительных свойств для цели ${NAME}_static
+      # ARCHIVE_OUTPUT_DIRECTORY: каталог для записи результатов сборки
+      # OUTPUT_NAME: базовое имя выходного файла (без учёта расширения)
+      set_target_properties(${NAME}_static
+        PROPERTIES
+          ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_LIBDIR}
+          OUTPUT_NAME ${ARG_OUTPUT_NAME})
+    endif()
+  endif()
+
+  # Если вызов был выполнен не из проекта верхнего уровня,
+  # то созданная цель исключается из цели `all`.
+  # При этом сама цель `${NAME}` может участвовать в сборке,
+  # если окажется в перечне зависимостей.
+  if(NOT PROJECT_IS_TOP_LEVEL)
+    set_target_properties(${NAME} PROPERTIES EXCLUDE_FROM_ALL True)
+    return()
+  endif()
+
+  # Правила для установки библиотек и относящихся к ним файлов.
+  # Если вызов был выполнен не из проекта верхнего уровня,
+  # то эти правила не обрабатываются.
+  write_basic_package_version_file(
+    ${CMAKE_CURRENT_BINARY_DIR}/${NAME}ConfigVersion.cmake
+    VERSION ${PROJECT_VERSION}
+    COMPATIBILITY AnyNewerVersion
+  )
+
+  configure_package_config_file(
+    ${MYX_CMAKE_LIB_DIR}/library-config.cmake.in
+    ${CMAKE_CURRENT_BINARY_DIR}/${NAME}Config.cmake
+    INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${NAME}
+    NO_SET_AND_CHECK_MACRO
+    NO_CHECK_REQUIRED_COMPONENTS_MACRO
+  )
+
+  install(EXPORT ${NAME}Targets
+    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${NAME}
+    COMPONENT dev
+  )
+
+  install(
+    FILES
+      ${PROJECT_BINARY_DIR}/${NAME}ConfigVersion.cmake
+      ${PROJECT_BINARY_DIR}/${NAME}Config.cmake
+    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${NAME}
+    COMPONENT dev
+  )
+
+  # Формирование файла для pkg-config
+  file(WRITE "${PROJECT_BINARY_DIR}/${NAME}.pc"
+    "prefix=${CMAKE_INSTALL_PREFIX}\n"
+    "exec_prefix=${CMAKE_INSTALL_PREFIX}\n"
+    "includedir=${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_INCLUDEDIR}\n")
+
+  if(NOT TYPE STREQUAL "INTERFACE")
+    file(APPEND "${PROJECT_BINARY_DIR}/${NAME}.pc"
+      "libdir=${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_LIBDIR}\n")
+  endif()
+
+  file(APPEND "${PROJECT_BINARY_DIR}/${NAME}.pc"
+    "\n"
+    "Name: ${NAME}\n"
+    "Description: ${NAME} library\n"
+    "Version: ${PROJECT_VERSION}\n"
+    "\n"
+    "Requires:\n"
+    "Cflags: -I${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_INCLUDEDIR}\n")
+
+  if(NOT TYPE STREQUAL "INTERFACE")
+    file(APPEND "${PROJECT_BINARY_DIR}/${NAME}.pc"
+      "Libs: -L${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_LIBDIR} -l${NAME}\n")
+  endif()
+
+  # Установка файла для pkg-config
+  install(
+    FILES "${PROJECT_BINARY_DIR}/${NAME}.pc"
+    COMPONENT dev
+    DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
+
+  if(TYPE STREQUAL "OBJECT")
+    # Установка динамической библиотеки
+    if(TARGET ${NAME}_shared)
+      install(
+        TARGETS ${NAME}_shared
+        EXPORT ${NAME}Targets
+        LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
+        COMPONENT lib
+      )
+    endif()
+
+    if(TARGET ${NAME}_static)
+      # Установка статической библиотеки
+      install(
+        TARGETS ${NAME}_static
+        EXPORT ${NAME}Targets
+        ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
+        COMPONENT static
+      )
+    endif()
+  endif()
+
+  if(TYPE STREQUAL "INTERFACE")
+    # Установка библиотеки из заголовочных файлов
+    install(
+      TARGETS ${NAME}
+      EXPORT ${NAME}Targets
+      COMPONENT lib
+    )
+  endif()
+endfunction()
--- a/MyxCMake/lib/ColoredMessages.cmake
+++ b/MyxCMake/lib/ColoredMessages.cmake
@ -0,0 +1,56 @@
+#[=======================================================================[.rst:
+
+Обёртки для функции `message()`, которые в терминале UNIX
+подсвечиают сообщения в зависимости от важности.
+
+#]=======================================================================]
+
+include_guard(GLOBAL)
+
+if(DEFINED ENV{TERM} AND UNIX)
+  string(ASCII 27 Esc)
+  set(MyxColorReset       "${Esc}[m")
+  set(MyxColorBold        "${Esc}[1m")
+  set(MyxColorRed         "${Esc}[31m")
+  set(MyxColorGreen       "${Esc}[32m")
+  set(MyxColorYellow      "${Esc}[33m")
+  set(MyxColorBlue        "${Esc}[34m")
+  set(MyxColorMagenta     "${Esc}[35m")
+  set(MyxColorCyan        "${Esc}[36m")
+  set(MyxColorWhite       "${Esc}[37m")
+  set(MyxColorBoldRed     "${Esc}[1;31m")
+  set(MyxColorBoldGreen   "${Esc}[1;32m")
+  set(MyxColorBoldYellow  "${Esc}[1;33m")
+  set(MyxColorBoldBlue    "${Esc}[1;34m")
+  set(MyxColorBoldMagenta "${Esc}[1;35m")
+  set(MyxColorBoldCyan    "${Esc}[1;36m")
+  set(MyxColorBoldWhite   "${Esc}[1;37m")
+endif()
+
+function(myx_message_fatal_error)
+  message(FATAL_ERROR ${MyxColorBoldRed}${ARGV}${MyxColorReset})
+endfunction()
+
+function(myx_message_send_error)
+  message(SEND_ERROR ${MyxColorBoldRed}${ARGV}${MyxColorReset})
+endfunction()
+
+function(myx_message_warning)
+  message(WARNING ${MyxColorRed}${ARGV}${MyxColorReset})
+endfunction()
+
+function(myx_message_deprecation)
+  message(DEPRECATION ${MyxColorBoldMagenta}${ARGV}${MyxColorReset})
+endfunction()
+
+function(myx_message_status)
+  message(STATUS ${MyxColorMagenta}${ARGV}${MyxColorReset})
+endfunction()
+
+function(myx_message_notice)
+  message(${MyxColorBold}${ARGV}${MyxColorReset})
+endfunction()
+
+function(myx_message)
+  message(${MyxColorReset}${ARGV}${MyxColorReset})
+endfunction()
--- a/MyxCMake/lib/CurrentDate.cmake
+++ b/MyxCMake/lib/CurrentDate.cmake
@ -0,0 +1,19 @@
+include_guard(GLOBAL)
+
+if(NOT MYX_TODAY)
+  if(WIN32)
+    execute_process(COMMAND "cmd" " /C date /T" OUTPUT_VARIABLE MYX_TODAY)
+  else()
+    execute_process(COMMAND "date" "+%d/%m/%Y" OUTPUT_VARIABLE MYX_TODAY)
+  endif()
+  string(REGEX REPLACE "(..)/(..)/(....).*" "\\3-\\2-\\1" MYX_TODAY ${MYX_TODAY})
+endif()
+
+if(NOT MYX_YEAR)
+  if(WIN32)
+    execute_process(COMMAND "cmd" " /C date /T" OUTPUT_VARIABLE MYX_YEAR)
+  else()
+    execute_process(COMMAND "date" "+%d/%m/%Y" OUTPUT_VARIABLE MYX_YEAR)
+  endif()
+  string(REGEX REPLACE "(..)/(..)/(....).*" "\\3" MYX_YEAR ${MYX_YEAR})
+endif()
--- a/MyxCMake/lib/DirectoriesGuards.cmake
+++ b/MyxCMake/lib/DirectoriesGuards.cmake
@ -0,0 +1,53 @@
+#[=======================================================================[.rst:
+
+Запись результатов сборки проекта внутрь иерархии каталогов с исходными текстами
+приводит к засорению файлами формируемыми на этапе сборки, которые затрудняют
+разработку, поиск в оригинальных файлах и мешают ориентироваться в проекте.
+При работе с несколькими типами сборки, например, отладка и выпуск, появляется
+необходимость корректного полного удаления результатов предыдущего варианта.
+
+#]=======================================================================]
+
+include_guard(GLOBAL)
+
+get_filename_component(cmake_source_dir "${CMAKE_SOURCE_DIR}" REALPATH)
+get_filename_component(cmake_binary_dir "${CMAKE_BINARY_DIR}" REALPATH)
+get_filename_component(project_source_dir "${PROJECT_SOURCE_DIR}" REALPATH)
+get_filename_component(project_binary_dir "${PROJECT_BINARY_DIR}" REALPATH)
+get_filename_component(cmake_install_prefix "${CMAKE_INSTALL_PREFIX}" REALPATH)
+
+if(cmake_install_prefix STREQUAL cmake_binary_dir)
+  myx_message_fatal_error(
+    "Myx: Cannot install into build directory ${CMAKE_INSTALL_PREFIX}.")
+endif()
+
+if(cmake_install_prefix STREQUAL cmake_source_dir)
+  myx_message_fatal_error(
+    "Myx: Cannot install into source directory ${CMAKE_INSTALL_PREFIX}.")
+endif()
+
+if(cmake_install_prefix STREQUAL project_binary_dir)
+  myx_message_fatal_error(
+    "Myx: Cannot install into build directory ${CMAKE_INSTALL_PREFIX}.")
+endif()
+
+if(cmake_install_prefix STREQUAL project_source_dir)
+  myx_message_fatal_error(
+    "Myx: Cannot install into source directory ${CMAKE_INSTALL_PREFIX}.")
+endif()
+
+if(cmake_binary_dir STREQUAL cmake_source_dir)
+  myx_message_fatal_error(
+    "Myx: Cannot build in source directory ${CMAKE_SOURCE_DIR}")
+endif()
+
+if(project_binary_dir STREQUAL project_source_dir)
+  myx_message_fatal_error(
+    "Myx: Cannot build in source directory ${CMAKE_SOURCE_DIR}")
+endif()
+
+unset(cmake_source_dir)
+unset(cmake_binary_dir)
+unset(project_source_dir)
+unset(project_binary_dir)
+unset(cmake_install_prefix)
--- a/MyxCMake/lib/FetchContentAdd.cmake
+++ b/MyxCMake/lib/FetchContentAdd.cmake
@ -0,0 +1,59 @@
+#[=======================================================================[.rst:
+FetchContent_Add
+----------------
+
+Вспомогательная функция для `FetchContent_Declare()`::
+
+    FetchContent_Add(NAME
+      [ GIT_REPOSITORY repo ] |
+      [ GIT_REMOTE remote ] |
+      [ GIT_PATH path ])
+
+Обязательные параметры: `NAME` - идентификатор загружаемого ресурса.
+Параметр `GIT_REPOSITORY` определяет имя репозитория по умолчанию.
+Если указана пара параметров `GIT_REMOTE` и `GIT_PATH` и у git-репозитория
+основного проекта указан удалённый репозиторий с именем, определяемым
+переменной `GIT_REMOTE`, то адрес репозитория для получения проекта
+изменяется. В этом случае загрузка будет производиться с сервера,
+определяемого из адреса с меткой `GIT_REMOTE`, и по пути `GIT_PATH`.
+
+#]=======================================================================]
+
+include_guard(GLOBAL)
+
+# Обязательно в глобальной области
+find_package(Git)
+
+function(FetchContent_Add NAME)
+  set(options "")
+  set(oneValueArgs GIT_REPOSITORY GIT_REMOTE GIT_PATH)
+  set(multiValueArgs "")
+
+  cmake_parse_arguments(ARG "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
+
+  if(GIT_FOUND AND ARG_GIT_REMOTE AND ARG_GIT_PATH)
+    execute_process(COMMAND ${GIT_EXECUTABLE} config --get remote.${ARG_GIT_REMOTE}.url OUTPUT_VARIABLE REMOTE_URL ERROR_QUIET)
+    if(REMOTE_URL)
+      string(REGEX REPLACE ":.*" "" SERVER ${REMOTE_URL})
+      string(FIND ${SERVER} "http" POS)
+      if(NOT POS EQUAL 0)
+        if(NOT SERVER STREQUAL REMOTE_URL)
+          set(ARG_GIT_REPOSITORY "${SERVER}:${ARG_GIT_PATH}")
+        endif()
+      endif()
+    endif()
+  endif()
+
+  FetchContent_Declare(
+    ${NAME}
+    ${ARG_UNPARSED_ARGUMENTS}
+    GIT_REPOSITORY ${ARG_GIT_REPOSITORY}
+    GIT_SHALLOW 1
+    )
+
+  if(NOT ${NAME}_POPULATED)
+    FetchContent_Populate(${NAME})
+    add_subdirectory(${${NAME}_SOURCE_DIR} ${${NAME}_BINARY_DIR})
+  endif()
+
+endfunction()
--- a/MyxCMake/lib/NinjaGeneratorWarning.cmake
+++ b/MyxCMake/lib/NinjaGeneratorWarning.cmake
@ -0,0 +1,8 @@
+# Версии CMake, как минимум до 3.8.0, генерируют некорректные
+# правила для ninja.
+
+include_guard(GLOBAL)
+
+if(${CMAKE_VERSION} VERSION_LESS "3.8.0" AND CMAKE_GENERATOR MATCHES Ninja)
+  myx_message_error("Myx: Old CMake versions should use Makefile generator")
+endif()
--- a/MyxCMake/lib/NinjaGeneratorWrapper.cmake
+++ b/MyxCMake/lib/NinjaGeneratorWrapper.cmake
@ -0,0 +1,11 @@
+# Если выбран генератор Ninja, то в основном сборочном каталоге создаётся
+# файл Makefile, который обрабатывается командой make и передаёт исполнение
+# системе сборки ninja. Таким образом можно выполнять команду make,
+# даже если правила сборки проекта сгенерированы для ninja.
+
+include_guard(GLOBAL)
+
+if(CMAKE_GENERATOR MATCHES Ninja AND PROJECT_IS_TOP_LEVEL)
+  file(WRITE ${CMAKE_BINARY_DIR}/Makefile
+    ".PHONY: build\n" "%:\n" "\t@ninja \$@\n" "build:\n" "\t@ninja\n")
+endif()
--- a/MyxCMake/lib/PopulateCMakeBinaryDir.cmake
+++ b/MyxCMake/lib/PopulateCMakeBinaryDir.cmake
@ -0,0 +1,15 @@
+include_guard(GLOBAL)
+
+# Создание в каталоге ${CMAKE_BINARY_DIR} стандартных каталогов bin,include,lib,
+# а также символических ссылок на каталоги в ${CMAKE_SOURCE_DIR}/files
+file(MAKE_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
+file(MAKE_DIRECTORY ${CMAKE_BINARY_DIR}/include)
+file(MAKE_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
+file(MAKE_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
+file(MAKE_DIRECTORY ${PROJECT_BINARY_DIR}/include)
+file(MAKE_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
+
+create_symlink("${CMAKE_SOURCE_DIR}/files/etc"   "${CMAKE_BINARY_DIR}/etc")
+create_symlink("${CMAKE_SOURCE_DIR}/files/log"   "${CMAKE_BINARY_DIR}/log")
+create_symlink("${CMAKE_SOURCE_DIR}/files/share" "${CMAKE_BINARY_DIR}/share")
+create_symlink("${CMAKE_SOURCE_DIR}/files/var"   "${CMAKE_BINARY_DIR}/var")
--- a/MyxCMake/lib/Qt5TargetSetup.cmake
+++ b/MyxCMake/lib/Qt5TargetSetup.cmake
@ -0,0 +1,94 @@
+include_guard(GLOBAL)
+
+function(myx_qt5_target_setup NAME)
+  set(options)
+  set(oneValueArgs)
+  set(multiValueArgs COMPONENTS PRIVATE PUBLIC_MOC PRIVATE_MOC UI QRC LANGS)
+
+  cmake_parse_arguments(ARG "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
+
+  get_target_property(target_type ${NAME} TYPE)
+
+  foreach(iter ${ARG_COMPONENTS})
+    if(target_type STREQUAL "INTERFACE_LIBRARY")
+      target_include_directories(${NAME} INTERFACE ${Qt5${iter}_INCLUDE_DIRS})
+    else()
+      target_include_directories(${NAME} PRIVATE ${Qt5${iter}_INCLUDE_DIRS})
+    endif()
+    if(target_type STREQUAL "EXECUTABLE" AND NOT iter STREQUAL "LinguistTools")
+      target_link_libraries(${NAME} PRIVATE "Qt5::${iter}")
+     endif()
+  endforeach()
+
+  foreach(iter ${ARG_PRIVATE})
+    if(target_type STREQUAL "INTERFACE_LIBRARY")
+      target_include_directories(${NAME} INTERFACE ${Qt5${iter}_PRIVATE_INCLUDE_DIRS})
+    else()
+      target_include_directories(${NAME} PRIVATE ${Qt5${iter}_PRIVATE_INCLUDE_DIRS})
+    endif()
+  endforeach()
+
+  if(target_type STREQUAL "EXECUTABLE")
+    target_compile_options(${NAME} PRIVATE ${Qt5Core_EXECUTABLE_COMPILE_FLAGS})
+  endif()
+
+  if(ARG_PUBLIC_MOC)
+    set_property(TARGET ${NAME} APPEND PROPERTY PUBLIC_HEADER_FILES "${ARG_PUBLIC_MOC}")
+    set_property(TARGET ${NAME} APPEND PROPERTY TR_FILES ${ARG_PUBLIC_MOC})
+  endif()
+
+  if(ARG_PRIVATE_MOC)
+    set_property(TARGET ${NAME} APPEND PROPERTY PRIVATE_HEADER_FILES "${ARG_PRIVATE_MOC}")
+    set_property(TARGET ${NAME} APPEND PROPERTY TR_FILES ${ARG_PRIVATE_MOC})
+  endif()
+
+  if(ARG_PUBLIC_MOC OR ARG_PRIVATE_MOC)
+    qt5_wrap_cpp(moc_cpp ${ARG_PUBLIC_MOC} ${ARG_PRIVATE_MOC})
+  endif()
+
+  if(ARG_QRC)
+    qt5_add_resources(qrc_cpp ${ARG_QRC})
+  endif()
+
+  if(ARG_UI AND "Widgets" IN_LIST ARG_COMPONENTS)
+    qt5_wrap_ui(ui_h ${ARG_UI})
+    set_property(TARGET ${NAME} APPEND PROPERTY TR_FILES ${ARG_UI})
+    # TODO
+    target_include_directories(${PROJECT_NAME} PRIVATE ${PROJECT_BINARY_DIR})
+  endif()
+
+  # Перечень файлов, подлежащих переводу
+  get_target_property(tr ${NAME} TR_FILES)
+  # Формирование файла ресурсов с переводами
+  if("LinguistTools" IN_LIST ARG_COMPONENTS AND tr)
+    # Заглавие файла ресурсов
+    file(WRITE ${PROJECT_BINARY_DIR}/${NAME}_l10n.qrc "<RCC><qresource prefix=\"/qm\">\n")
+    # Для каждого языка, указанное в параметре LANGS
+    foreach(iter ${ARG_LANGS})
+      # Создание или обновление файла переводов в каталоге ${PROJECT_SOURCE_DIR}/l10n
+      # и его компиляция в каталог ${PROJECT_BINARY_DIR}
+      qt5_create_translation(qm ${tr} "${PROJECT_SOURCE_DIR}/l10n/${NAME}_${iter}.ts")
+      # Добавление записи для скомпилированного файла переводов в ресурсный файл
+      file(APPEND ${PROJECT_BINARY_DIR}/${NAME}_l10n.qrc
+        "<file alias=\"${NAME}_${iter}\">${NAME}_${iter}.qm</file>\n")
+      # Добавление скомпилированного файла переводов к списку зависимостей для цели
+      target_sources(${NAME} PRIVATE ${qm})
+    endforeach()
+    # Окончение файла ресурсов
+    file(APPEND ${PROJECT_BINARY_DIR}/${NAME}_l10n.qrc "</qresource></RCC>\n")
+    # Комплияция файла ресурсов с переводами
+    qt5_add_resources(qrc_l10n ${PROJECT_BINARY_DIR}/${NAME}_l10n.qrc)
+    target_sources(${NAME} PRIVATE ${qrc_l10n})
+  endif()
+  unset(tr)
+  target_sources(${NAME} PRIVATE ${ARG_PUBLIC_MOC} ${ARG_PRIVATE_MOC} ${moc_cpp} ${ui_h} ${qrc_cpp})
+
+  # Установка публичных заголовочных файлов
+  if(PROJECT_IS_TOP_LEVEL)
+    install_relative(${PROJECT_SOURCE_DIR}
+      FILES ${ARG_PUBLIC_MOC}
+      DESTINATION ${CMAKE_INSTALL_PREFIX}
+      COMPONENT dev
+     )
+  endif()
+endfunction()
--- a/MyxCMake/lib/SemanticProjectVersion.cmake
+++ b/MyxCMake/lib/SemanticProjectVersion.cmake
@ -0,0 +1,17 @@
+include_guard(GLOBAL)
+
+function(myx_is_semantic_project_version)
+  if(NOT ${PROJECT_VERSION_PATCH} MATCHES "([0-9]+)")
+    myx_message_error("Myx: Please set project version in X.Y.Z format")
+  endif()
+endfunction()
+
+function(myx_project_version_int)
+  # cmake-format: off
+  myx_is_semantic_project_version()
+  math(EXPR v "(${PROJECT_VERSION_MAJOR} << 32) + (${PROJECT_VERSION_MINOR} << 16) + ${PROJECT_VERSION_PATCH}")
+  set_property(GLOBAL PROPERTY PROJECT_VERSION_INT ${v})
+  # cmake-format: on
+endfunction()
+
+myx_is_semantic_project_version()
--- a/MyxCMake/lib/TargetSetup.cmake
+++ b/MyxCMake/lib/TargetSetup.cmake
@ -0,0 +1,89 @@
+include_guard(GLOBAL)
+
+function(myx_target_setup NAME)
+  set(options)
+  set(oneValueArgs PCH)
+  set(multiValueArgs COMPILE_DEFINITIONS PACKAGES LINK_LIBRARIES
+                     CPP INTERFACE_HEADERS PUBLIC_HEADERS PRIVATE_HEADERS)
+
+  cmake_parse_arguments(ARG "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
+
+  if(NOT TARGET ${NAME})
+    myx_message_fatal_error("Target ${NAME} does not exists.")
+  endif()
+
+  get_target_property(target_type ${NAME} TYPE)
+
+  foreach(iter ${ARG_PACKAGES})
+    target_include_directories(${NAME} PRIVATE ${${iter}_INCLUDE_DIRS})
+    target_compile_definitions(${NAME} PRIVATE ${${iter}_COMPILE_DEFINITIONS})
+  endforeach()
+  target_compile_definitions(${NAME} PRIVATE ${ARG_COMPILE_DEFINITIONS})
+
+  if(ARG_CPP)
+    set_property(TARGET ${NAME} APPEND PROPERTY CPP_FILES ${ARG_CPP})
+    set_property(TARGET ${NAME} APPEND PROPERTY TR_FILES ${ARG_CPP})
+  endif()
+
+  if(ARG_PUBLIC_HEADERS)
+    set_property(TARGET ${NAME} APPEND PROPERTY PUBLIC_HEADER_FILES "${ARG_PUBLIC_HEADERS}")
+    set_property(TARGET ${NAME} APPEND PROPERTY TR_FILES ${ARG_PUBLIC_HEADERS})
+  endif()
+
+  if(ARG_PRIVATE_HEADERS)
+    set_property(TARGET ${NAME} APPEND PROPERTY PRIVATE_HEADER_FILES "${ARG_PRIVATE_HEADERS}")
+    set_property(TARGET ${NAME} APPEND PROPERTY TR_FILES ${ARG_PRIVATE_HEADERS})
+  endif()
+
+  if(ARG_PCH)
+    if((${CMAKE_VERSION} VERSION_GREATER_EQUAL 3.16) AND (PROJECT_IS_TOP_LEVEL OR MYX_USE_LOCAL_DIRECTORIES))
+      target_precompile_headers(${NAME} PRIVATE ${ARG_PCH})
+    else()
+      target_compile_options(${NAME} PRIVATE -include ${ARG_PCH})
+    endif()
+    set_property(TARGET ${NAME} APPEND PROPERTY PRIVATE_HEADER_FILES "${ARG_PCH}")
+  endif()
+
+  if(NOT target_type STREQUAL "INTERFACE_LIBRARY")
+    target_include_directories(${PROJECT_NAME} PRIVATE
+      $<BUILD_INTERFACE:${PROJECT_BINARY_DIR}/include>)
+
+    if(IS_DIRECTORY "${PROJECT_SOURCE_DIR}/src")
+      target_include_directories(${PROJECT_NAME} PRIVATE
+        $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/src>)
+    endif()
+  endif()
+
+  if(target_type STREQUAL "EXECUTABLE")
+    if(IS_DIRECTORY "${PROJECT_SOURCE_DIR}/include")
+      target_include_directories(${PROJECT_NAME} PRIVATE
+        $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include>)
+    endif()
+
+    set_target_properties(${NAME} PROPERTIES
+      POSITION_INDEPENDENT_CODE ON
+      RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_BINDIR}
+    )
+    if(CMAKE_CXX_COMPILE_OPTIONS_PIE)
+      target_compile_options(${NAME} PUBLIC ${CMAKE_CXX_COMPILE_OPTIONS_PIE})
+    endif()
+    install(TARGETS ${NAME} COMPONENT main RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
+  endif()
+
+  target_sources(${NAME} PUBLIC $<BUILD_INTERFACE:${ARG_INTERFACE_HEADERS}>)
+  target_sources(${NAME} PUBLIC ${ARG_PUBLIC_HEADERS})
+  target_sources(${NAME} PRIVATE ${ARG_CPP} ${ARG_PCH} ${ARG_PRIVATE_HEADERS})
+  if(NOT target_type STREQUAL "OBJECT_LIBRARY")
+    target_link_libraries(${NAME} PRIVATE ${ARG_LINK_LIBRARIES})
+  endif()
+  target_compile_definitions(${NAME} PRIVATE ${ARG_COMPILE_DEFINITIONS})
+
+  # Установка публичных заголовочных файлов
+  if(PROJECT_IS_TOP_LEVEL)
+    install_relative(${PROJECT_SOURCE_DIR}
+      FILES ${ARG_PUBLIC_HEADERS} ${ARG_INTERFACE_HEADERS}
+      DESTINATION ${CMAKE_INSTALL_PREFIX}
+      COMPONENT dev
+    )
+  endif()
+endfunction()
--- a/MyxCMake/lib/Uncrustify.cmake
+++ b/MyxCMake/lib/Uncrustify.cmake
@ -0,0 +1,108 @@
+include_guard(GLOBAL)
+
+find_program(UNCRUSTIFY_EXE NAMES uncrustify)
+
+if(UNCRUSTIFY_EXE)
+  if(NOT EXISTS ${PROJECT_BINARY_DIR}/uncrustify-classheader.txt)
+    file(GENERATE OUTPUT ${PROJECT_BINARY_DIR}/uncrustify-classheader.txt CONTENT
+"/**
+ *  @class   $(fclass)
+ *  @brief   TODO
+ *  @details TODO
+ */")
+  endif()
+
+  if(NOT EXISTS ${PROJECT_BINARY_DIR}/uncrustify-filefooter.txt)
+    file(GENERATE OUTPUT ${PROJECT_BINARY_DIR}/uncrustify-filefooter.txt CONTENT
+    "// EOF $(filename)")
+  endif()
+
+  if(NOT EXISTS ${PROJECT_BINARY_DIR}/uncrustify-fileheader.txt)
+    file(GENERATE OUTPUT ${PROJECT_BINARY_DIR}/uncrustify-fileheader.txt CONTENT
+"/**
+ *  @file    $(filename)
+ *  @brief   TODO
+ *  @details TODO
+ */")
+  endif()
+
+  if(NOT EXISTS ${PROJECT_BINARY_DIR}/uncrustify-funcheader.txt)
+    file(GENERATE OUTPUT ${PROJECT_BINARY_DIR}/uncrustify-funcheader.txt CONTENT
+"/**
+ *  @fn $(fclass)::$(function)
+ *  $(javaparam)
+ *  @details TODO
+ */")
+  endif()
+endif()
+
+
+function(myx_uncrustify target)
+  set(options)
+  set(oneValueArgs CONFIG)
+  set(multiValueArgs)
+
+  cmake_parse_arguments(ARG "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
+
+  if(NOT ARG_CONFIG)
+    set(ARG_CONFIG "${PROJECT_SOURCE_DIR}/.uncrustify.cfg")
+    if(NOT EXISTS ${ARG_CONFIG})
+      set(ARG_CONFIG "${CMAKE_SOURCE_DIR}/.uncrustify.cfg")
+    endif()
+  endif()
+
+  if(NOT EXISTS ${ARG_CONFIG})
+    myx_message_notice("MyxCMake: uncrustify config is not found")
+    return()
+  endif()
+
+  if(NOT UNCRUSTIFY_EXE)
+    myx_message_notice("MyxCMake: uncrustify executable is not found")
+    return()
+  endif()
+
+  if(NOT TARGET myx-uncrustify)
+    add_custom_target(myx-uncrustify)
+  endif()
+  if(NOT TARGET myx-uncrustify-check)
+    add_custom_target(myx-uncrustify-check)
+  endif()
+  if(NOT TARGET myx-uncrustify-append-comments)
+    add_custom_target(myx-uncrustify-append-comments)
+  endif()
+
+  get_target_property(__sources ${target} SOURCES)
+  list(FILTER __sources EXCLUDE REGEX "qrc_.*\\.cpp$")
+  list(FILTER __sources EXCLUDE REGEX "moc_.*\\.cpp$")
+  list(FILTER __sources EXCLUDE REGEX "ui_.*\\.h$")
+  list(FILTER __sources EXCLUDE REGEX ".*\\.qm$")
+
+  add_custom_command(OUTPUT ${PROJECT_BINARY_DIR}/uncrustify-${target}.cfg
+                     COMMAND ${UNCRUSTIFY_EXE} --update-config-with-doc
+                                               -c ${ARG_CONFIG}
+                                               -o ${PROJECT_BINARY_DIR}/uncrustify-${target}.cfg)
+  list(APPEND UNCRUSTIFY_OPTS -c ${PROJECT_BINARY_DIR}/uncrustify-${target}.cfg)
+  # cmake-format: off
+  add_custom_target(${target}-uncrustify-check
+    DEPENDS ${PROJECT_BINARY_DIR}/uncrustify-${target}.cfg
+    COMMAND ${UNCRUSTIFY_EXE} ${UNCRUSTIFY_OPTS} --check ${__sources})
+
+  list(APPEND UNCRUSTIFY_OPTS --replace --no-backup)
+  add_custom_target(${target}-uncrustify
+    DEPENDS ${PROJECT_BINARY_DIR}/uncrustify-${target}.cfg
+    COMMAND ${UNCRUSTIFY_EXE} ${UNCRUSTIFY_OPTS} --mtime ${__sources})
+
+  add_custom_target(${target}-uncrustify-append-comments
+    DEPENDS ${PROJECT_BINARY_DIR}/uncrustify-${target}.cfg
+    COMMAND ${UNCRUSTIFY_EXE} ${UNCRUSTIFY_OPTS}
+            --set cmt_insert_class_header=${PROJECT_BINARY_DIR}/uncrustify-classheader.txt
+            --set cmt_insert_file_footer=${PROJECT_BINARY_DIR}/uncrustify-filefooter.txt
+            --set cmt_insert_file_header=${PROJECT_BINARY_DIR}/uncrustify-fileheader.txt
+            --set cmt_insert_func_header=${PROJECT_BINARY_DIR}/uncrustify-funcheader.txt
+            --set cmt_insert_before_ctor_dtor=true  --mtime ${__sources})
+  # cmake-format: on
+
+  add_dependencies(myx-uncrustify ${target}-uncrustify)
+  add_dependencies(myx-uncrustify-check ${target}-uncrustify-check)
+  add_dependencies(myx-uncrustify-append-comments ${target}-uncrustify-append-comments)
+endfunction()
--- a/MyxCMake/lib/doc/Doxyfile.in
+++ b/MyxCMake/lib/doc/Doxyfile.in
@ -0,0 +1,31 @@
+PROJECT_NAME           = @DOXYGEN_PROJECT_TITLE@
+OUTPUT_DIRECTORY       = @DOXYGEN_OUTPUT_DIRECTORY@
+OUTPUT_LANGUAGE        = @ARG_LANGUAGE@
+STRIP_FROM_PATH        = @PROJECT_SOURCE_DIR@
+STRIP_FROM_INC_PATH    = @PROJECT_SOURCE_DIR@
+
+EXTRACT_ALL            = YES
+EXTRACT_PRIVATE        = YES
+EXTRACT_STATIC         = YES
+EXTRACT_LOCAL_METHODS  = YES
+
+INPUT                  = "@PROJECT_SOURCE_DIR@/doc/doxygen" "@PROJECT_SOURCE_DIR@/include" "@PROJECT_SOURCE_DIR@/src"
+RECURSIVE              = YES
+
+CLANG_ASSISTED_PARSING = YES
+CLANG_DATABASE_PATH    = @CMAKE_BINARY_DIR@
+
+GENERATE_HTML          = @ARG_HTML@
+GENERATE_TREEVIEW      = YES
+
+GENERATE_LATEX         = @ARG_LATEX@
+LATEX_CMD_NAME         = xelatex
+COMPACT_LATEX          = YES
+
+GENERATE_XML           = @ARG_XML@
+
+UML_LOOK               = YES
+TEMPLATE_RELATIONS     = YES
+CALL_GRAPH             = YES
+CALLER_GRAPH           = YES
+INTERACTIVE_SVG        = YES
--- a/MyxCMake/lib/doc/Doxygen.cmake
+++ b/MyxCMake/lib/doc/Doxygen.cmake
@ -0,0 +1,65 @@
+include_guard(GLOBAL)
+
+function(myx_doc_doxygen NAME)
+  find_package(Doxygen)
+  if(DOXYGEN_FOUND)
+    set(DOXYGEN_FOUND ON CACHE STRING "Doxygen documentation generator enabled" FORCE)
+    set(DOXYGEN_EXECUTABLE "${DOXYGEN_EXECUTABLE}" CACHE STRING "Path to Doxygen executable")
+  else()
+    set(DOXYGEN_FOUND OFF CACHE STRING "Doxygen documentation generator disabled" FORCE)
+  endif()
+
+  set(target "myx-doc-doxygen-${NAME}")
+  if(NOT DOXYGEN_FOUND)
+    add_custom_target(${target} VERBATIM COMMENT "Doxygen is not found. Skipping target ${target} build")
+    return()
+  endif()
+
+  if(TARGET ${target})
+    myx_message_warning("Target ${target} already defined")
+    return()
+  endif()
+
+  set(options)
+  set(oneValueArgs HTML LATEX XML LANGUAGE DOXYFILE_TEMPLATE)
+  set(multiValueArgs)
+
+  cmake_parse_arguments(ARG "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
+
+  if(NOT ARG_HTML)
+    set(ARG_HTML NO)
+  endif()
+  if(NOT ARG_LATEX)
+    set(ARG_LATEX NO)
+  endif()
+  if(NOT ARG_XML)
+    set(ARG_XML YES)
+  endif()
+  if(NOT ARG_LANGUAGE)
+    set(ARG_LANGUAGE "Russian")
+  endif()
+  if(NOT ARG_DOXYFILE_TEMPLATE OR NOT EXISTS "${ARG_DOXYFILE_TEMPLATE}")
+    set(ARG_DOXYFILE_TEMPLATE "${MYX_CMAKE_LIB_DIR}/doc/Doxyfile.in")
+  endif()
+  if(NOT DOXYGEN_PROJECT_NAME)
+    set(DOXYGEN_PROJECT_NAME ${PROJECT_NAME})
+  endif()
+
+  set(work_dir ${PROJECT_BINARY_DIR}/doc/doxygen)
+  configure_file(${ARG_DOXYFILE_TEMPLATE} ${work_dir}/Doxyfile @ONLY)
+
+  add_custom_target(${target}
+    VERBATIM
+    WORKING_DIRECTORY ${work_dir}
+    COMMAND ${DOXYGEN_EXECUTABLE} ${work_dir}/Doxyfile
+    COMMENT "Generating API documentation with Doxygen")
+  if(ARG_HTML)
+    install(DIRECTORY ${CMAKE_BINARY_DIR}/doc/doxygen/html/
+            COMPONENT doc OPTIONAL
+            DESTINATION ${CMAKE_INSTALL_DATADIR}/doc/doxygen)
+  endif()
+  if(NOT TARGET myx-doc-doxygen)
+    add_custom_target(myx-doc-doxygen)
+  endif()
+  add_dependencies(myx-doc-doxygen ${target})
+endfunction()
--- a/MyxCMake/lib/generators/GitInfo.cmake
+++ b/MyxCMake/lib/generators/GitInfo.cmake
@ -0,0 +1,32 @@
+cmake_policy(PUSH)
+cmake_policy(SET CMP0053 NEW) # IN_LIST operator
+
+set(ARG_PREFIX "${PREFIX}")
+set(GIT_REV "N/A")
+set(GIT_DIFF "")
+set(GIT_TAG "N/A")
+set(GIT_BRANCH "N/A")
+
+find_package(Git)
+
+if(GIT_EXECUTABLE)
+  execute_process(COMMAND ${GIT_EXECUTABLE} log --pretty=format:'%h' -n 1 OUTPUT_VARIABLE GIT_REV ERROR_QUIET)
+
+  # Check whether we got any revision (which isn't always the case,
+  # e.g. when someone downloaded a zip file from Github instead of a checkout)
+  if(NOT "${GIT_REV}" STREQUAL "")
+    execute_process(COMMAND bash -c "${GIT_EXECUTABLE} diff --quiet --exit-code || echo +" OUTPUT_VARIABLE GIT_DIFF)
+    execute_process(COMMAND ${GIT_EXECUTABLE} describe --exact-match --tags OUTPUT_VARIABLE GIT_TAG ERROR_QUIET)
+    execute_process(COMMAND ${GIT_EXECUTABLE} rev-parse --abbrev-ref HEAD OUTPUT_VARIABLE GIT_BRANCH)
+
+    string(STRIP "${GIT_REV}" GIT_REV)
+    string(SUBSTRING "${GIT_REV}" 1 7 GIT_REV)
+    string(STRIP "${GIT_DIFF}" GIT_DIFF)
+    string(STRIP "${GIT_TAG}" GIT_TAG)
+    string(STRIP "${GIT_BRANCH}" GIT_BRANCH)
+  endif()
+endif()
+
+configure_file("GitInfo.hpp.in" "${GIT_INFO_FILE}")
+
+cmake_policy(POP)
--- a/MyxCMake/lib/generators/GitInfo.hpp.in
+++ b/MyxCMake/lib/generators/GitInfo.hpp.in
@ -0,0 +1,25 @@
+#pragma once
+
+#if defined (@PREFIX@GIT_REV)
+#error "Duplicate definition of macros @PREFIX@GIT_REV"
+#else
+#define @PREFIX@GIT_REV "@GIT_REV@"
+#endif
+
+#if defined (@PREFIX@GIT_DIFF)
+#error "Duplicate definition of macros @PREFIX@GIT_DIFF"
+#else
+#define @PREFIX@GIT_DIFF "@GIT_DIFF@"
+#endif
+
+#if defined (@PREFIX@GIT_BRANCH)
+#error "Duplicate definition of macros @PREFIX@GIT_BRANCH"
+#else
+#define @PREFIX@GIT_BRANCH "@GIT_BRANCH@"
+#endif
+
+#if defined (@PREFIX@GIT_TAG)
+#error "Duplicate definition of macros @PREFIX@GIT_TAG"
+#else
+#define @PREFIX@GIT_TAG "@GIT_TAG@"
+#endif
--- a/MyxCMake/lib/generators/GitInfoHeader.cmake
+++ b/MyxCMake/lib/generators/GitInfoHeader.cmake
@ -0,0 +1,46 @@
+#[=======================================================================[.rst:
+myx_generate_git_info_header
+----------------------------------
+
+Вспомогательная функция для автоматической генерации заголовочного
+файла, содержащего информацию о текущем состоянии репозитория git::
+
+    myx_generate_git_info_header(TARGET BASE_FILENAME
+      [ PREFIX prefix ] )
+
+Обязательные параметры: `TARGET` - имя цели, с которой связан заголовочный файл,
+и `BASE_FILENAME` - имя генерируемого заголовочного файла. Дополнительный аргумент
+`PREFIX` добавляет префикс к генерируемым именам переменных.
+
+#]=======================================================================]
+
+include_guard(GLOBAL)
+
+function(myx_generate_git_info_header target base_filename)
+  set(options)
+  set(oneValueArgs PREFIX)
+  set(multiValueArgs)
+
+  cmake_parse_arguments(ARG "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
+
+  set(filename "${PROJECT_BINARY_DIR}/include/${base_filename}")
+
+  set(PREFIX "")
+  if(ARG_PREFIX)
+    string(APPEND ARG_PREFIX "_")
+    string(REPLACE "-" "_" PREFIX ${ARG_PREFIX})
+  endif()
+
+# cmake-format: off
+  if(NOT TARGET ${target}-git-info-header)
+    add_custom_target(${target}-git-info-header ALL
+      ${CMAKE_COMMAND} -DGIT_INFO_FILE=${filename} -DPREFIX=${PREFIX}
+                       -P ${MYX_CMAKE_LIB_DIR}/generators/GitInfo.cmake
+      BYPRODUCTS ${filename}
+      WORKING_DIRECTORY ${MYX_CMAKE_LIB_DIR}/generators)
+  endif()
+# cmake-format: on
+
+  set_property(TARGET ${target} APPEND PROPERTY PRIVATE_HEADER_FILES ${filename})
+  target_sources(${target} PRIVATE ${filename})
+endfunction()
--- a/MyxCMake/lib/generators/PrivateConfig.hpp.in
+++ b/MyxCMake/lib/generators/PrivateConfig.hpp.in
@ -0,0 +1,11 @@
+#pragma once
+
+#define PROJECT_VERSION_STR "@PROJECT_VERSION@"
+#define PROJECT_VERSION_INT @PROJECT_VERSION_INT@
+
+#cmakedefine PROJECT_NAME "@PROJECT_NAME@"
+#cmakedefine AUTHOR_NAME "@AUTHOR_NAME@"
+#cmakedefine AUTHOR_EMAIL "@AUTHOR_EMAIL@"
+#cmakedefine DESCRIPTION "@PROJECT_DESCRIPTION@"
+#cmakedefine BUILD_TYPE "@CMAKE_BUILD_TYPE@"
+#cmakedefine BUILD_DATE "@MYX_TODAY@"
--- a/MyxCMake/lib/generators/PrivateConfigHeader.cmake
+++ b/MyxCMake/lib/generators/PrivateConfigHeader.cmake
@ -0,0 +1,27 @@
+#[=======================================================================[.rst:
+myx_generate_private_config_header
+----------------------------------
+
+Вспомогательная функция для автоматической генерации заголовочного
+файла, содержащего информацию о проекте::
+
+    myx_generate_private_config_header(TARGET BASE_FILENAME)
+
+Обязательные параметры: `TARGET` - имя цели, с которой связан заголовочный файл,
+и `BASE_FILENAME` - имя генерируемого заголовочного файла.
+
+#]=======================================================================]
+
+include_guard(GLOBAL)
+
+function(myx_generate_private_config_header target base_filename)
+  set(BUILD_DATE ${MYX_TODAY})
+  myx_project_version_int()
+  get_property(PROJECT_VERSION_INT GLOBAL PROPERTY PROJECT_VERSION_INT)
+
+  set(filename "${PROJECT_BINARY_DIR}/include/${base_filename}")
+  configure_file("${MYX_CMAKE_LIB_DIR}/generators/PrivateConfig.hpp.in" ${filename})
+
+  set_property(TARGET ${target} APPEND PROPERTY PRIVATE_HEADER_FILES ${filename})
+  target_sources(${target} PRIVATE ${filename})
+endfunction()
--- a/MyxCMake/lib/library-config.cmake.in
+++ b/MyxCMake/lib/library-config.cmake.in
@ -0,0 +1,5 @@
+@PACKAGE_INIT@
+
+include("${CMAKE_CURRENT_LIST_DIR}/@PROJECT_NAME@Targets.cmake")
+
+check_required_components("@PROJECT_NAME@")
--- a/MyxCMake/lib/macro/CreateSymlink.cmake
+++ b/MyxCMake/lib/macro/CreateSymlink.cmake
@ -0,0 +1,11 @@
+include_guard(GLOBAL)
+
+macro(create_symlink original linkname)
+  if(NOT EXISTS ${linkname})
+    if(${CMAKE_VERSION} VERSION_LESS "3.14.0")
+      execute_process(COMMAND ${CMAKE_COMMAND} -E create_symlink ${original} ${linkname})
+    else()
+      file(CREATE_LINK ${original} ${linkname} SYMBOLIC)
+    endif()
+  endif()
+endmacro(create_symlink original linkname)
--- a/MyxCMake/lib/macro/FindPackages.cmake
+++ b/MyxCMake/lib/macro/FindPackages.cmake
@ -0,0 +1,35 @@
+include_guard(GLOBAL)
+
+macro(myx_find_packages)
+  set(options)
+  set(oneValueArgs)
+  set(multiValueArgs PACKAGES Boost Qt5 Qt5Private)
+
+  cmake_parse_arguments(ARG "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
+
+  foreach(iter ${ARG_PACKAGES})
+    find_package(${iter} REQUIRED)
+  endforeach()
+
+  if(ARG_Boost)
+    find_package(Boost COMPONENTS ${ARG_Boost} REQUIRED)
+  endif()
+
+  if(ARG_Qt5)
+    find_package(Qt5 COMPONENTS ${ARG_Qt5} REQUIRED)
+  endif()
+
+  if(ARG_Qt5Private)
+    foreach(iter ${ARG_Qt5Private})
+      find_package("Qt5${iter}" COMPONENTS Private REQUIRED)
+    endforeach()
+  endif()
+
+  foreach(iter IN LISTS oneValueArgs multiValueArgs)
+    unset(ARG_${iter})
+  endforeach()
+  unset(ARG_UNPARSED_ARGUMENTS)
+  unset(multiValueArgs)
+  unset(oneValueArgs)
+  unset(options)
+endmacro(myx_find_packages)
--- a/MyxCMake/lib/macro/InstallRelative.cmake
+++ b/MyxCMake/lib/macro/InstallRelative.cmake
@ -0,0 +1,19 @@
+#[=======================================================================[.rst:
+install_relative
+----------------
+
+#]=======================================================================]
+
+macro(install_relative STRIP_DIRECTORY)
+  set(options)
+  set(oneValueArgs DESTINATION)
+  set(multiValueArgs FILES)
+
+  cmake_parse_arguments(ARG "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
+
+  foreach(FILE ${ARG_FILES})
+    get_filename_component(DIR ${FILE} DIRECTORY)
+    string(REPLACE ${STRIP_DIRECTORY} "" RELATIVE_DIR ${DIR})
+    INSTALL(FILES ${FILE} DESTINATION ${ARG_DESTINATION}/${RELATIVE_DIR} ${ARG_UNPARSED_ARGUMENTS})
+  endforeach()
+endmacro(install_relative STRIP_DIRECTORY)