1.99.3

lib/AddLibrary.cmake

@@ -0,0 +1,56 @@
+include_guard(GLOBAL)
+
+include(GenerateExportHeader)
+include(GNUInstallDirs)
+
+function(myx_add_library)
+  set(options)
+  set(oneValueArgs PCH TYPE)
+  set(multiValueArgs SOURCES COMPILE_DEFINITIONS)
+  cmake_parse_arguments(arg "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
+
+  if(NOT arg_TYPE)
+    set(arg_TYPE "OBJECT")
+  endif()
+
+  add_library(${PROJECT_NAME} ${arg_TYPE})
+
+  if(arg_TYPE STREQUAL INTERFACE)
+    target_include_directories(${PROJECT_NAME}
+      INTERFACE
+        $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include>
+        $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
+    )
+  else()
+    target_include_directories(${PROJECT_NAME}
+      PUBLIC
+        $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include>
+      PRIVATE
+        $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
+    )
+
+    set_target_properties(${PROJECT_NAME} PROPERTIES POSITION_INDEPENDENT_CODE ON)
+
+    string(TOUPPER ${PROJECT_NAME} suffix)
+    generate_export_header(${PROJECT_NAME}
+        BASE_NAME "${suffix}"
+        EXPORT_MACRO_NAME "EXPORT_${suffix}"
+        DEPRECATED_MACRO_NAME "DEPRECATED_${suffix}"
+        NO_DEPRECATED_MACRO_NAME "NO_DEPRECATED_${suffix}"
+        NO_EXPORT_MACRO_NAME "NO_EXPORT_${suffix}"
+        STATIC_DEFINE "STATIC_DEFINE_${suffix}"
+        EXPORT_FILE_NAME "${PROJECT_SOURCE_DIR}/include/${PROJECT_NAME}/export.hpp"
+        DEFINE_NO_DEPRECATED
+    )
+  endif()
+
+  if(arg_PCH)
+    if(${CMAKE_VERSION} VERSION_GREATER_EQUAL 3.16)
+      target_precompile_headers(${PROJECT_NAME} PRIVATE ${PROJECT_SOURCE_DIR}/${arg_PCH})
+    else()
+      target_compile_options(${PROJECT_NAME} PRIVATE -include ${PROJECT_SOURCE_DIR}/${arg_PCH})
+    endif()
+  endif()
+
+  target_compile_definitions(${PROJECT_NAME} PRIVATE ${arg_COMPILE_DEFINITIONS})
+endfunction()

lib/Qt5TargetSetup.cmake

@@ -0,0 +1,42 @@
+include_guard(GLOBAL)
+
+function(myx_qt5_target_setup)
+  set(options)
+  set(oneValueArgs)
+  set(multiValueArgs COMPONENTS PRIVATE SOURCES MOC UI QRC LANGS)
+  cmake_parse_arguments(arg "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
+
+  if(arg_COMPONENTS)
+    find_package(Qt5 COMPONENTS ${arg_COMPONENTS} REQUIRED)
+    foreach(iter ${arg_COMPONENTS})
+      target_include_directories(${PROJECT_NAME} PRIVATE ${Qt5${iter}_INCLUDE_DIRS})
+    endforeach()
+  endif()
+
+  if(arg_PRIVATE)
+    foreach(iter ${arg_PRIVATE})
+      find_package(Qt5${iter} COMPONENTS Private REQUIRED)
+    endforeach()
+  endif()
+
+  qt5_wrap_cpp(moc_cpp ${arg_MOC})
+  qt5_wrap_ui(ui_h ${arg_UI})
+  qt5_add_resources(qrc_cpp ${arg_QRC})
+
+  if("LinguistTools" IN_LIST arg_COMPONENTS)
+    set(ts)
+    foreach(iter ${arg_LANGS})
+      list(APPEND ts ${PROJECT_SOURCE_DIR}/l10n/${PROJECT_NAME}_${iter}.ts)
+    endforeach()
+
+    qt5_create_translation(qm
+      ${PROJECT_SOURCE_DIR}/include
+      ${PROJECT_SOURCE_DIR}/src
+      ${ts}
+    )
+  endif()
+
+  target_sources(${PROJECT_NAME}
+    PRIVATE
+      ${arg_SOURCES} ${moc_cpp} ${ui_h} ${qrc_cpp} ${qm})
+endfunction()