include_guard(GLOBAL)

function(myx_target_setup NAME)
  set(options)
  set(oneValueArgs PCH)
  set(multiValueArgs COMPILE_DEFINITIONS FIND_PACKAGES LINK_LIBRARIES
                     CPP PUBLIC_HEADERS PRIVATE_HEADERS SOURCES)

  cmake_parse_arguments(ARG "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  if(NOT TARGET ${NAME})
    myx_message_fatal_error("Target ${NAME} does not exists.")
  endif()

  get_target_property(type ${NAME} TYPE)

  foreach(iter ${ARG_FIND_PACKAGES})
    find_package(${iter} REQUIRED)
    target_include_directories(${NAME} PRIVATE ${${iter}_INCLUDE_DIRS})
    target_compile_definitions(${NAME} PRIVATE ${${iter}_COMPILE_DEFINITIONS})
  endforeach()
  target_compile_definitions(${NAME} PRIVATE ${ARG_COMPILE_DEFINITIONS})

  if(ARG_SOURCES)
    myx_message_fatal_error("MyxCMake: Use of SOURCES argument")
  endif()

  if(ARG_CPP)
    set_property(TARGET ${NAME} APPEND PROPERTY CPP_FILES ${ARG_CPP})
  endif()

  if(ARG_PUBLIC_HEADERS)
    set_property(TARGET ${NAME} APPEND PROPERTY PUBLIC_HEADER_FILES "${ARG_PUBLIC_HEADERS}")
  endif()

  if(ARG_PUBLIC_HEADERS)
    set_property(TARGET ${NAME} APPEND PROPERTY PRIVATE_HEADER_FILES "${ARG_PRIVATE_HEADERS}")
  endif()

  if(ARG_PCH)
    if(${CMAKE_VERSION} VERSION_GREATER_EQUAL 3.16)
      target_precompile_headers(${NAME} PRIVATE ${ARG_PCH})
    else()
      target_compile_options(${NAME} PRIVATE -include ${ARG_PCH})
    endif()
    set_property(TARGET ${NAME} APPEND PROPERTY PRIVATE_HEADER_FILES "${ARG_PCH}")
  endif()

  target_include_directories(${PROJECT_NAME} PRIVATE
    $<BUILD_INTERFACE:${PROJECT_BINARY_DIR}/include>)

  if(IS_DIRECTORY "${PROJECT_SOURCE_DIR}/src")
    target_include_directories(${PROJECT_NAME} PRIVATE
        $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/src>)
  endif()

  if(type STREQUAL EXECUTABLE)
    if(IS_DIRECTORY "${PROJECT_SOURCE_DIR}/include")
      target_include_directories(${PROJECT_NAME} PRIVATE
        $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include>)
    endif()

    set_target_properties(${NAME} PROPERTIES
      POSITION_INDEPENDENT_CODE ON
      RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_BINDIR}
    )
    if(CMAKE_CXX_COMPILE_OPTIONS_PIE)
      target_compile_options(${NAME} PUBLIC ${CMAKE_CXX_COMPILE_OPTIONS_PIE})
    endif()
    install(TARGETS ${NAME} COMPONENT main RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
  endif()

  target_sources(${NAME} PUBLIC ${ARG_PUBLIC_HEADERS})
  target_sources(${NAME} PRIVATE ${ARG_CPP} ${ARG_PCH} ${ARG_PRIVATE_HEADERS})
  target_link_libraries(${NAME} PRIVATE ${ARG_LINK_LIBRARIES})
  target_compile_definitions(${NAME} PRIVATE ${ARG_COMPILE_DEFINITIONS})

  # Установка публичных заголовочных файлов
  install_relative(${PROJECT_SOURCE_DIR}
    FILES ${ARG_PUBLIC_HEADERS}
    DESTINATION ${CMAKE_INSTALL_PREFIX}
    COMPONENT dev
   )
endfunction()