# Подключение внешних проектов
include(ExternalProject)

# cmake-format: off
list(APPEND _ext_project_args
  libfsp
  DEPENDS libpreprocmath libionobase myxlib
  SOURCE_DIR  ${CMAKE_SOURCE_DIR}/thirdparty/libfsp
  INSTALL_DIR ${CMAKE_BINARY_DIR}
  BYPRODUCTS  <INSTALL_DIR>/${CMAKE_INSTALL_LIBDIR}/libfsp.a
  CMAKE_ARGS  ${CMLIB_EXT_PROJ_DEFAULT_ARGS}
              -DPREPROCMATH_PREFIX=${CMAKE_BINARY_DIR}
              -DIONOBASE_PREFIX=${CMAKE_BINARY_DIR}
              -DMYXLIB_PREFIX=${CMAKE_BINARY_DIR}
              <SOURCE_DIR>)
if(FspThirdparty_FIND_COMPONENTS STREQUAL "headers")
  list(APPEND _ext_project_args
    BUILD_COMMAND     true
    INSTALL_COMMAND   ${CMAKE_MAKE_PROGRAM} fsp-install-headers)
endif()
ExternalProject_Add(${_ext_project_args})
unset(_ext_project_args)

set(FSP_IS_EXTERNAL_PROJECT ON CACHE BOOL "" FORCE)
# cmake-format: on

set(FSP_PREFIX
    ${CMAKE_BINARY_DIR}
    CACHE FILEPATH "" FORCE)
set(FSP_INCLUDE_DIR
    ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_INCLUDEDIR}
    CACHE PATH "" FORCE)
set(FSP_INCLUDE_DIRS
    ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_INCLUDEDIR}
    CACHE PATH "" FORCE)
set(FSP_LIBRARY_DIR
    ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_LIBDIR}
    CACHE PATH "" FORCE)
set(FSP_LIBRARIES
    ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_LIBDIR}/libfsp.a
    CACHE FILEPATH "" FORCE)