set(BUILD_BREATHE_DOC OFF CACHE STRING "Enable documntation in Breathe format")
set_property(CACHE BUILD_BREATHE_DOC PROPERTY STRINGS ON OFF)

function(add_breathe_target)
  if(BUILD_BREATHE_DOC)
    find_package(Doxygen REQUIRED)
    find_package(Perl REQUIRED)
    set(Python_ADDITIONAL_VERSIONS 3.7 3.6 3.5 3.4 3.3 3.2)
    find_package(PythonInterp REQUIRED)
    find_package(Sphinx REQUIRED)
    include(FindPythonModule)
    find_python_module(breathe REQUIRED)
    find_python_module(recommonmark REQUIRED)

    set(options)
    set(oneValueArgs SOURCE_DIR BUILD_DIR CACHE_DIR HTML_DIR DOXY_FILE CONF_FILE TARGET_NAME COMMENT)
    set(multiValueArgs)

    cmake_parse_arguments(_BREATHE "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

    configure_file(${_BREATHE_CONF_FILE} ${_BREATHE_BUILD_DIR}/conf.py @ONLY)
    configure_file(${_BREATHE_DOXY_FILE} ${_BREATHE_BUILD_DIR}/Doxyfile @ONLY)

    add_custom_target(${_BREATHE_TARGET_NAME} ALL VERBATIM
      COMMAND ${SPHINX_EXECUTABLE} -q -b html -c ${_BREATHE_BUILD_DIR}
                                              -d ${_BREATHE_CACHE_DIR}
                                                 ${_BREATHE_SOURCE_DIR}
                                                 ${_BREATHE_HTML_DIR}
      COMMENT "Building ${_BREATHE_TARGET_NAME} documentation with Breathe"
      )
  endif()
endfunction()