cmake_policy(SET CMP0057 NEW)

# Добавление конфигурации для профилирования
if(CMAKE_CONFIGURATION_TYPES)
  if(NOT "Profile" IN_LIST CMAKE_CONFIGURATION_TYPES)
    list(APPEND CMAKE_CONFIGURATION_TYPES Profile)
  endif()
else()
  set(_allowed_build_types None Debug Release Profile)
  set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${_allowed_build_types})
  if(NOT CMAKE_BUILD_TYPE)
    set(CMAKE_BUILD_TYPE Debug CACHE STRING "" FORCE)
  elseif(NOT "${CMAKE_BUILD_TYPE}" IN_LIST _allowed_build_types)
    message(FATAL_ERROR "Invalid build type: ${CMAKE_BUILD_TYPE}")
  endif()
endif()

if(CMAKE_BUILD_TYPE STREQUAL Profile)
  # Ключи компиляции для режима профилирования в зависимости от типа компилятора
  if (CMAKE_CXX_COMPILER_IS_Clang OR CMAKE_CXX_COMPILER_IS_GCC)
    set(CMAKE_C_FLAGS_PROFILE             "${CMAKE_C_FLAGS_RELEASE} -g -p"             CACHE STRING "")
    set(CMAKE_CXX_FLAGS_PROFILE           "${CMAKE_CXX_FLAGS_RELEASE} -g -p"           CACHE STRING "")
    set(CMAKE_EXE_LINKER_FLAGS_PROFILE    "${CMAKE_EXE_LINKER_FLAGS_RELEASE} -g -p"    CACHE STRING "")
    set(CMAKE_SHARED_LINKER_FLAGS_PROFILE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE}"       CACHE STRING "")
    set(CMAKE_STATIC_LINKER_FLAGS_PROFILE "${CMAKE_STATIC_LINKER_FLAGS_RELEASE}"       CACHE STRING "")
    set(CMAKE_MODULE_LINKER_FLAGS_PROFILE "${CMAKE_MODULE_LINKER_FLAGS_RELEASE} -g -p" CACHE STRING "")
  elseif (CMAKE_CXX_COMPILER_IS_Intel)
    message("Set options for profiling with Intel C++")
  elseif (CMAKE_CXX_COMPILER_IS_MSVC)
    message("Set options for profiling with Visual Studio C++")
  endif()
  set(PROFILE 1)
elseif(CMAKE_BUILD_TYPE STREQUAL Debug)
  # В режиме отладки подробный вывод сообщений компилятора
  set(CMAKE_VERBOSE_MAKEFILE 1)
  set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
  set(DEBUG 1)
elseif(CMAKE_BUILD_TYPE STREQUAL Release)
  set(RELEASE 1)
elseif(CMAKE_BUILD_TYPE STREQUAL None)
  # Режим None используется для статического анализа кода
  set(ANALYSIS 1)
  set(CMAKE_VERBOSE_MAKEFILE 1)
  set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
  #  set(USE_CLANG_TIDY ON CACHE BOOL "Use clang-tidy")
  #  set(USE_CPPCHECK ON CACHE BOOL "Use cppcheck")
  #  set(USE_PVS_STUDIO ON CACHE BOOL "Use PVS-Studio")
endif()