myx-cmake-example-features/cmake/myx/lib/Qt5TargetSetup.cmake

include_guard(GLOBAL)

function(myx_qt5_target_setup TARGET_NAME)
  set(options)
  set(oneValueArgs)
  set(multiValueArgs COMPONENTS PRIVATE PUBLIC_MOC PRIVATE_MOC UI QRC LANGS)

  cmake_parse_arguments(ARG "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  get_target_property(__target_type ${TARGET_NAME} TYPE)

  foreach(iter ${ARG_COMPONENTS})
    if(__target_type STREQUAL "INTERFACE_LIBRARY")
      target_include_directories(${TARGET_NAME} INTERFACE ${Qt5${iter}_INCLUDE_DIRS})
    else()
      target_include_directories(${TARGET_NAME} PRIVATE ${Qt5${iter}_INCLUDE_DIRS})
    endif()
    if(NOT iter STREQUAL "LinguistTools")
      if(__target_type STREQUAL "EXECUTABLE")
        target_link_libraries(${TARGET_NAME} PRIVATE "Qt5::${iter}")
      endif()
      if((__target_type STREQUAL "SHARED_LIBRARY") OR (__target_type STREQUAL "OBJECT_LIBRARY"))
        target_link_libraries(${TARGET_NAME} PUBLIC "Qt5::${iter}")
      endif()
    endif()
  endforeach()

  foreach(iter ${ARG_PRIVATE})
    if(__target_type STREQUAL "INTERFACE_LIBRARY")
      target_include_directories(${TARGET_NAME} INTERFACE ${Qt5${iter}_PRIVATE_INCLUDE_DIRS})
    else()
      target_include_directories(${TARGET_NAME} PRIVATE ${Qt5${iter}_PRIVATE_INCLUDE_DIRS})
    endif()
  endforeach()

  if(__target_type STREQUAL "EXECUTABLE")
    target_compile_options(${TARGET_NAME} PRIVATE ${Qt5Core_EXECUTABLE_COMPILE_FLAGS})
  endif()

  if(ARG_PUBLIC_MOC)
    set_property(TARGET ${TARGET_NAME} APPEND PROPERTY PUBLIC_HEADER_FILES "${ARG_PUBLIC_MOC}")
    set_property(TARGET ${TARGET_NAME} APPEND PROPERTY TR_FILES ${ARG_PUBLIC_MOC})
  endif()

  if(ARG_PRIVATE_MOC)
    set_property(TARGET ${TARGET_NAME} APPEND PROPERTY PRIVATE_HEADER_FILES "${ARG_PRIVATE_MOC}")
    set_property(TARGET ${TARGET_NAME} APPEND PROPERTY TR_FILES ${ARG_PRIVATE_MOC})
  endif()

  if(ARG_PUBLIC_MOC OR ARG_PRIVATE_MOC)
    qt5_wrap_cpp(moc_cpp ${ARG_PUBLIC_MOC} ${ARG_PRIVATE_MOC})
  endif()

  if(ARG_QRC)
    qt5_add_resources(qrc_cpp ${ARG_QRC})
  endif()

  if(ARG_UI AND "Widgets" IN_LIST ARG_COMPONENTS)
    qt5_wrap_ui(ui_h ${ARG_UI})
    set_property(TARGET ${TARGET_NAME} APPEND PROPERTY TR_FILES ${ARG_UI})
    # TODO
    target_include_directories(${PROJECT_NAME} PRIVATE ${PROJECT_BINARY_DIR})
  endif()

  # Перечень файлов, подлежащих переводу
  if(__target_type STREQUAL "INTERFACE_LIBRARY")
    get_target_property(tr ${TARGET_NAME} INTERFACE_TR_FILES)
  else()
    get_target_property(tr ${TARGET_NAME} TR_FILES)
  endif()
  # Формирование файла ресурсов с переводами
  if("LinguistTools" IN_LIST ARG_COMPONENTS AND tr)
    # Заглавие файла ресурсов
    file(WRITE ${PROJECT_BINARY_DIR}/${TARGET_NAME}_l10n.qrc "<RCC><qresource prefix=\"/qm\">\n")
    # Для каждого языка, указанное в параметре LANGS
    foreach(iter ${ARG_LANGS})
      # Создание или обновление файла переводов в каталоге ${PROJECT_SOURCE_DIR}/l10n
      # и его компиляция в каталог ${PROJECT_BINARY_DIR}
      qt5_create_translation(qm ${tr}
        "${PROJECT_SOURCE_DIR}/l10n/${TARGET_NAME}_${iter}.ts"
        OPTIONS -I ${PROJECT_SOURCE_DIR}/include -I ${PROJECT_SOURCE_DIR}/include/${PROJECT_NAME})
      # Добавление записи для скомпилированного файла переводов в ресурсный файл
      file(APPEND ${PROJECT_BINARY_DIR}/${TARGET_NAME}_l10n.qrc
        "<file alias=\"${TARGET_NAME}_${iter}\">${TARGET_NAME}_${iter}.qm</file>\n")
      # Добавление скомпилированного файла переводов к списку зависимостей для цели
      target_sources(${TARGET_NAME} PRIVATE ${qm})
    endforeach()
    # Окончение файла ресурсов
    file(APPEND ${PROJECT_BINARY_DIR}/${TARGET_NAME}_l10n.qrc "</qresource></RCC>\n")
    # Комплияция файла ресурсов с переводами
    qt5_add_resources(qrc_l10n ${PROJECT_BINARY_DIR}/${TARGET_NAME}_l10n.qrc)
    target_sources(${TARGET_NAME} PRIVATE ${qrc_l10n})
  endif()
  unset(tr)
  if(__target_type STREQUAL "INTERFACE_LIBRARY")
    target_sources(${TARGET_NAME} INTERFACE ${ARG_PUBLIC_MOC} ${ARG_PRIVATE_MOC} ${moc_cpp} ${ui_h} ${qrc_cpp})
  else()
    target_sources(${TARGET_NAME} PRIVATE ${ARG_PUBLIC_MOC} ${ARG_PRIVATE_MOC} ${moc_cpp} ${ui_h} ${qrc_cpp})
  endif()

  # Установка публичных заголовочных файлов
  if(PROJECT_IS_TOP_LEVEL)
    myx_install_relative(${PROJECT_SOURCE_DIR}
      FILES ${ARG_PUBLIC_MOC}
      DESTINATION ${CMAKE_INSTALL_PREFIX}
      COMPONENT DEV
     )
  endif()
endfunction()