54 lines
2.1 KiB
CMake
54 lines
2.1 KiB
CMake
|
#[=======================================================================[.rst:
|
|||
|
myx_generate_git_info_header
|
|||
|
----------------------------------
|
|||
|
|
|||
|
Вспомогательная функция для автоматической генерации заголовочного
|
|||
|
файла, содержащего информацию о текущем состоянии репозитория git::
|
|||
|
|
|||
|
myx_generate_git_info_header(TARGET BASE_FILENAME
|
|||
|
[ PREFIX prefix ] )
|
|||
|
|
|||
|
Обязательные параметры: `TARGET` - имя цели, с которой связан заголовочный файл,
|
|||
|
и `BASE_FILENAME` - имя генерируемого заголовочного файла. Дополнительный аргумент
|
|||
|
`PREFIX` добавляет префикс к генерируемым именам переменных.
|
|||
|
|
|||
|
#]=======================================================================]
|
|||
|
|
|||
|
include_guard(GLOBAL)
|
|||
|
|
|||
|
if(${CMAKE_VERSION} VERSION_LESS "3.17.0")
|
|||
|
set(MYX_CMAKE_LIB_GENERATORS_DIR_BACKPORT "${CMAKE_CURRENT_LIST_DIR}")
|
|||
|
endif()
|
|||
|
|
|||
|
function(myx_generate_git_info_header target base_filename)
|
|||
|
if(${CMAKE_VERSION} VERSION_LESS "3.17.0")
|
|||
|
set(CMAKE_CURRENT_FUNCTION_LIST_DIR ${MYX_CMAKE_LIB_GENERATORS_DIR_BACKPORT})
|
|||
|
endif()
|
|||
|
|
|||
|
set(options)
|
|||
|
set(oneValueArgs PREFIX)
|
|||
|
set(multiValueArgs)
|
|||
|
cmake_parse_arguments(ARG "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
|
|||
|
|
|||
|
set(filename "${PROJECT_BINARY_DIR}/include/${base_filename}")
|
|||
|
|
|||
|
set(PREFIX "")
|
|||
|
if(ARG_PREFIX)
|
|||
|
string(APPEND ARG_PREFIX "_")
|
|||
|
string(REPLACE "-" "_" PREFIX ${ARG_PREFIX})
|
|||
|
endif()
|
|||
|
|
|||
|
# cmake-format: off
|
|||
|
if(NOT TARGET ${target}-git-info-header)
|
|||
|
add_custom_target(${target}-git-info-header ALL
|
|||
|
${CMAKE_COMMAND} -DGIT_INFO_FILE=${filename} -DPREFIX=${PREFIX}
|
|||
|
-P ${CMAKE_CURRENT_FUNCTION_LIST_DIR}/GitInfo.cmake
|
|||
|
BYPRODUCTS ${filename}
|
|||
|
WORKING_DIRECTORY ${CMAKE_CURRENT_FUNCTION_LIST_DIR})
|
|||
|
endif()
|
|||
|
# cmake-format: on
|
|||
|
|
|||
|
set_property(TARGET ${target} APPEND PROPERTY PRIVATE_HEADER_FILES ${filename})
|
|||
|
target_sources(${target} PRIVATE ${filename})
|
|||
|
endfunction()
|