# Название основной цели и имя библиотеки в текущем каталоге
set(TRGT redis)

# cmake-format: off
# Список файлов исходных текстов
set(TRGT_cpp
    ${CMAKE_CURRENT_SOURCE_DIR}/client.cpp
    ${CMAKE_CURRENT_SOURCE_DIR}/lexer.cpp
    ${CMAKE_CURRENT_SOURCE_DIR}/parser.cpp
    ${CMAKE_CURRENT_SOURCE_DIR}/request.cpp)

# Список заголовочных файлов (используется для установки)
set(TRGT_moc_hpp
    ${CMAKE_CURRENT_SOURCE_DIR}/client.hpp
    ${CMAKE_CURRENT_SOURCE_DIR}/lexer.hpp
    ${CMAKE_CURRENT_SOURCE_DIR}/parser.hpp
    ${CMAKE_CURRENT_SOURCE_DIR}/request.hpp)

set(TRGT_hpp
    ${CMAKE_CURRENT_SOURCE_DIR}/reply.hpp
    ${CMAKE_CURRENT_SOURCE_DIR}/client-inl.hpp
    ${CMAKE_CURRENT_SOURCE_DIR}/lexer-inl.hpp
    ${CMAKE_CURRENT_SOURCE_DIR}/parser-inl.hpp
    ${CMAKE_CURRENT_SOURCE_DIR}/request-inl.hpp)

set(TRGT_headers ${TRGT_moc_hpp} ${TRGT_hpp})
# cmake-format: on

qt5_wrap_cpp(TRGT_moc_cpp ${TRGT_moc_hpp})

add_library(${TRGT}-header-only INTERFACE)
target_include_directories(
  ${TRGT}-header-only SYSTEM INTERFACE "$<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}/include>"
                                       "$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>")

if(MYXLIB_BUILD_LIBRARIES)
  add_common_library(${TRGT} OUTPUT_NAME myx-${TRGT} SOURCES ${TRGT_moc_cpp} ${TRGT_cpp} ${TRGT_headers})
  common_target_properties(${TRGT})

  # Создание цели для проверки утилитой clang-tidy
  add_clang_tidy_check(${TRGT} ${TRGT_cpp} ${TRGT_headers})

  # Создание цели для проверки утилитой clang-analyze
  add_clang_analyze_check(${TRGT} ${TRGT_cpp} ${TRGT_headers})

  # Создание цели для проверки утилитой clazy
  add_clazy_check(${TRGT} ${TRGT_cpp} ${TRGT_headers})

  # Создание цели для проверки утилитой pvs-studio
  add_pvs_check(${TRGT})

  # Создание цели для автоматического форматирования кода
  add_format_sources(${TRGT} ${TRGT_cpp} ${TRGT_headers})

  target_compile_definitions(${TRGT} PUBLIC MYXLIB_BUILD_LIBRARIES)
  target_include_directories(${TRGT} SYSTEM PUBLIC ${Qt5Core_INCLUDE_DIRS})
  target_include_directories(${TRGT} SYSTEM PUBLIC ${Qt5Network_INCLUDE_DIRS})
  target_include_directories(${TRGT} SYSTEM PRIVATE ${CMAKE_SOURCE_DIR}/src)

  cotire(${TRGT})
  install(TARGETS ${TRGT}_static COMPONENT libs-dev ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR})
  if(BUILD_SHARED_LIBS)
    install(TARGETS ${TRGT}_shared COMPONENT main LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
  endif()
endif()

generate_pkgconfig(myx-${TRGT} COMPONENT base-dev INSTALL_LIBRARY ${MYXLIB_BUILD_LIBRARIES})
install(FILES ${TRGT_headers} COMPONENT base-dev DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${PROJECT_NAME}/${TRGT})

# Цель, используемая только для установки заголовочных файлов без компиляции проекта
add_custom_target(${TRGT}-install-headers COMMAND ${CMAKE_COMMAND} -DCMAKE_INSTALL_COMPONENT=base-dev -P
                                                  "${CMAKE_BINARY_DIR}/cmake_install.cmake")