# Название основной цели и имя библиотеки в текущем каталоге
set(TRGT filesystem)

# cmake-format: off
# Список файлов исходных текстов
set(TRGT_sources
    ${CMAKE_CURRENT_SOURCE_DIR}/current_executable.cpp
    ${CMAKE_CURRENT_SOURCE_DIR}/paths.cpp
    ${CMAKE_CURRENT_SOURCE_DIR}/paths_mt.cpp)

# Список заголовочных файлов
set(TRGT_headers
    ${CMAKE_CURRENT_SOURCE_DIR}/current_executable.hpp
    ${CMAKE_CURRENT_SOURCE_DIR}/paths.hpp
    ${CMAKE_CURRENT_SOURCE_DIR}/paths_mt.hpp)
# cmake-format: on

add_common_library(${TRGT} OUTPUT_NAME myx-${TRGT} SOURCES ${TRGT_sources})
common_target_properties(${TRGT})

# Создание цели для проверки утилитой clang-tidy
add_clang_tidy_check(${TRGT} ${TRGT_sources})

# Создание цели для проверки утилитой clang-analyze
add_clang_analyze_check(${TRGT} ${TRGT_sources})

# Создание цели для проверки утилитой clazy
add_clazy_check(${TRGT} ${TRGT_sources})

# Создание цели для проверки утилитой pvs-studio
add_pvs_check(${TRGT})

# Создание цели для автоматического форматирования кода
add_format_sources(${TRGT} ${TRGT_sources} ${TRGT_headers})

target_include_directories(${TRGT} SYSTEM PUBLIC ${Qt5Core_INCLUDE_DIRS})
target_include_directories(${TRGT} SYSTEM PRIVATE ${CMAKE_SOURCE_DIR}/src)
target_include_directories(${TRGT} PRIVATE ${CMAKE_BINARY_DIR}/include)

cotire(${TRGT})

# Цель, используемая только для установки заголовочных файлов без компиляции проекта
add_custom_target(${TRGT}-install-headers COMMAND "${CMAKE_COMMAND}" -DCMAKE_INSTALL_COMPONENT=DEV -P
                                                  "${CMAKE_BINARY_DIR}/cmake_install.cmake")

# Правила для установки
install(TARGETS ${TRGT}_static COMPONENT DEV ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR})
if(BUILD_SHARED_LIBS)
  install(TARGETS ${TRGT}_shared COMPONENT DEV LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
endif()
install(FILES ${TRGT_headers} COMPONENT DEV DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${PROJECT_NAME}/${TRGT})
install(FILES ${CMAKE_BINARY_DIR}/${TRGT}.pc COMPONENT DEV DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig)