# Название основной цели и имя библиотеки в текущем каталоге
set(current_target filesystem)

# Список файлов исходных текстов
set(current_target_sources
  ${CMAKE_CURRENT_SOURCE_DIR}/current_executable.cpp
  ${CMAKE_CURRENT_SOURCE_DIR}/paths.cpp
)

# Список заголовочных файлов (используется для установки)
set(current_target_headers
  ${CMAKE_CURRENT_SOURCE_DIR}/current_executable.hpp
  ${CMAKE_CURRENT_SOURCE_DIR}/paths.hpp
)

add_common_library(TARGET ${current_target}
                   OUTPUT_NAME myx-${current_target}
                   SOURCES ${current_target_sources})
common_target_properties(${current_target})

add_clang_tidy_check(${current_target} ${current_target_sources})
add_clang_analyze_check(${current_target} ${current_target_sources})
add_clazy_check(${current_target} ${current_target_sources})
add_pvs_check(${current_target})

# Форматирование исходников
add_format_sources(${current_target} ${current_target_sources} ${current_target_headers})

target_include_directories(${current_target} SYSTEM PUBLIC ${Qt5Core_INCLUDE_DIRS})
target_include_directories(${current_target} SYSTEM PRIVATE ${CMAKE_SOURCE_DIR}/src)
target_include_directories(${current_target} PRIVATE ${CMAKE_BINARY_DIR}/include)

# Цель, используемая только для установки заголовочных файлов без компиляции проекта
add_custom_target(${current_target}-install-headers
  COMMAND "${CMAKE_COMMAND}"
  -DCMAKE_INSTALL_COMPONENT=headers -P "${CMAKE_BINARY_DIR}/cmake_install.cmake"
  )

set_target_properties(${current_target}
  PROPERTIES
  OUTPUT_NAME myx-filesystem
  RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_BINDIR}
  )

# Правила для установки
install(TARGETS ${current_target}_static ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR})
if(BUILD_SHARED_LIBS)
  install(TARGETS ${current_target}_shared LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
endif()
install(FILES ${current_target_headers}
        COMPONENT headers
        DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${PROJECT_NAME}/${current_target})
install(FILES ${CMAKE_BINARY_DIR}/${current_target}.pc DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig)