# Название основной цели и имя библиотеки в текущем каталоге
set(TRGT math)

# cmake-format: off
# Список файлов исходных текстов
set(TRGT_cpp
    ${CMAKE_CURRENT_SOURCE_DIR}/almost_equal_relative.cpp
    ${CMAKE_CURRENT_SOURCE_DIR}/almost_equal_relative_and_abs.cpp
    ${CMAKE_CURRENT_SOURCE_DIR}/almost_equal_ulps.cpp
    ${CMAKE_CURRENT_SOURCE_DIR}/almost_equal_ulps_and_abs.cpp
    ${CMAKE_CURRENT_SOURCE_DIR}/constants.cpp)

# Список заголовочных файлов
set(TRGT_hpp
    ${CMAKE_CURRENT_SOURCE_DIR}/all.hpp
    ${CMAKE_CURRENT_SOURCE_DIR}/almost_equal_relative.hpp
    ${CMAKE_CURRENT_SOURCE_DIR}/almost_equal_relative-inl.hpp
    ${CMAKE_CURRENT_SOURCE_DIR}/almost_equal_relative_and_abs.hpp
    ${CMAKE_CURRENT_SOURCE_DIR}/almost_equal_relative_and_abs-inl.hpp
    ${CMAKE_CURRENT_SOURCE_DIR}/almost_equal_ulps.hpp
    ${CMAKE_CURRENT_SOURCE_DIR}/almost_equal_ulps-inl.hpp
    ${CMAKE_CURRENT_SOURCE_DIR}/almost_equal_ulps_and_abs.hpp
    ${CMAKE_CURRENT_SOURCE_DIR}/almost_equal_ulps_and_abs-inl.hpp
    ${CMAKE_CURRENT_SOURCE_DIR}/constants.hpp
    ${CMAKE_CURRENT_SOURCE_DIR}/constants-inl.hpp
    ${CMAKE_CURRENT_SOURCE_DIR}/float_cmp_types.hpp
    ${CMAKE_CURRENT_SOURCE_DIR}/functions.hpp
    ${CMAKE_CURRENT_SOURCE_DIR}/radar.hpp
    ${CMAKE_CURRENT_SOURCE_DIR}/units.hpp)

set(TRGT_headers ${TRGT_hpp})
# cmake-format: on

add_library(${TRGT}-header-only INTERFACE)
target_sources(${TRGT}-header-only INTERFACE ${TRGT_headers})
target_include_directories(
  ${TRGT}-header-only SYSTEM INTERFACE "$<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}/include>"
                                       "$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>")

if(MYXLIB_BUILD_LIBRARIES)

  add_common_library(${TRGT} OUTPUT_NAME myx-${TRGT} SOURCES ${TRGT_cpp} ${TRGT_headers})
  common_target_properties(${TRGT})

  # Создание цели для проверки утилитой clang-tidy
  add_clang_tidy_check(${TRGT} ${TRGT_sources} ${TRGT_headers})

  # Создание цели для проверки утилитой clang-analyze
  add_clang_analyze_check(${TRGT} ${TRGT_sources} ${TRGT_headers})

  # Создание цели для проверки утилитой clazy
  add_clazy_check(${TRGT} ${TRGT_sources} ${TRGT_headers})

  # Создание цели для проверки утилитой pvs-studio
  add_pvs_check(${TRGT})

  # Создание цели для автоматического форматирования кода
  add_format_sources(${TRGT} ${TRGT_sources} ${TRGT_headers})

  target_compile_definitions(${TRGT} PUBLIC MYXLIB_BUILD_LIBRARIES)
  target_include_directories(${TRGT} SYSTEM PRIVATE ${CMAKE_SOURCE_DIR}/src)

  cotire(${TRGT})
  install(TARGETS ${TRGT}_static COMPONENT DEV ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR})
  if(BUILD_SHARED_LIBS)
    install(TARGETS ${TRGT}_shared COMPONENT DEV LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
  endif()
endif()

install(FILES ${TRGT_headers} COMPONENT DEV DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${PROJECT_NAME}/${TRGT})
install(FILES ${CMAKE_BINARY_DIR}/${TRGT}.pc COMPONENT DEV DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig)

# Цель, используемая только для установки заголовочных файлов без компиляции проекта
add_custom_target(${TRGT}-install-headers COMMAND "${CMAKE_COMMAND}" -DCMAKE_INSTALL_COMPONENT=DEV -P
                                                  "${CMAKE_BINARY_DIR}/cmake_install.cmake")